想要把程式寫好，一定要不斷地研究、改進，由錯誤中學習，由改進中得到經驗，培養出敏銳的觀察能力和良好的寫作習慣。
在開始時，這種過程需要付出不少時間，但對一位程式師來說，寫程式是終身職業，能不精益求精嗎？
以下舉兩個實例，以說明如何研究改進已完成的程式。
1,指令的運用：
以下面這段通訊處理程式而論，不僅語法及指令完全正確，執行時也毫無錯誤，是不是還可以加以改進呢？
1-1 按照前面規定，說明項中已用簡化的字串：
SND-傳送 RCV-接收 LET-左
RGT-右 VER-直 HOR-橫
1-2 程式師代號為'C'。
1-3 段名省略。
1: CSND0:
2: MOV DX,03FDH ; 輸出埠
3: MOV AL,80H
4: OUT DX,AL ; 輸出指令
5: MOV DX,03F8H ; LSB 速度控制
6: MOV AL,06H ; 速度=19200/秒
7: OUT DX,AL
8: MOV DX,03F9H ; MSB 速度控制
9: MOV AL,0 ; 速度=19200/秒
10: OUT DX,AL
11: MOV DX,03FBH ; 行控制暫存器
12: MOV AL,03H ; NO PARITY,1
; STOP,8
13: OUT DX,AL
14: MOV DX,03FCH ; 通訊控制
15: OUT DX,AL
16: MOV DX,03F9H ; 中斷有效
17: MOV AL,0
18: OUT DX,AL
19: CSND1:
20: MOV DX,03FDH ; 狀態暫存器
21: IN AL,DX
22: TEST AL,10H ; 是否可接收?
23: JNZ CRCV0 ; 可
24: TEST AL,20H ; 通道已清否?
25: JZ CSND1 ; 8250未清
26: MOV AH,1 ; 鍵盤有輸入?
27: INT 16H
28: CMP AL,07H ; ='CTRL+G'
29: JE CEND ; 是，完畢
30: MOV DX,03F8H
31: OUT DX,AL ; 送輸入字符
32: JMP CSND1
33: CRCV0: ; 接收
34: MOV DX,03FCH ; 通訊控制
35: MOV AL,08H ; 暫停中斷
36: OUT DX,AL
37: MOV DX,3F8H
38: IN AL,DX ; 收字符
39: MOV AH,0EH
40: INT 10H ; 螢屏顯示
41: MOV DX,03FCH
42: MOV AL,0BH
43: OUT DX,AL ; 繼續接受
44: JMP CSND1 ; 循環工作
45: CEND:
46: RET ; 完成
本段程式共 84 個字元，非常精簡，但仍然有節省的餘地，要點在DX的數值上。
DX值由 03F8H到 03FDH，可知 DH 之值不變，只需改變 DL 即可。每改變DX一次，需要三個字元，如僅變DL，只需兩個字元。這一指令共用了十一次，除第一次有必要外，其他十次就可以省下10個字元。
再要斤斤計較，還可以搾出二個字元來，在５至８條中，若用INC DX 只需要一個字元。
此外，31，32及43 ,44是浪費的作法，只要在第18條加一標號，就可以省卻兩個字元輸出的指令。另外，還有35及39兩條指令，應該合併，一次即將AX設妥，於是，又省下了一個字元。
先令 DH=3
1: CSEND0:
2: MOV DL,0FDH ; 輸出埠
3: MOV AL,80H
4: OUT DX,AL ; 輸出指令
5: MOV DL,0F8H ; LSB 速度控制
6: MOV AL,06H ; 速度=19200/秒
7: OUT DX,AL
8: INC DX ; MSB 速度控制
9: SUB AL,AL ; 速度=19200/秒
10: OUT DX,AL
11: MOV DL,0FBH ; 行控制暫存器
12: MOV AL,DH ;NO PARITY,1
; STOP,8
13: OUT DX,AL
14: INC DX ; 通訊控制
15: OUT DX,AL
16: MOV DL,0F9H ; 中斷有效
17: SUB AL,AL
18: CSNDA:
19: OUT DX,AL
20: CSND1:
21: MOV DL,0FDH ; 狀態暫存器
22: IN AL,DX
23: TEST AL,10H ; 是否可接收?
24: JNZ CRCV0 ; 可
25: TEST AL,20H ; 通道已清否?
26: JZ CSND1 ; 8250未清
27: MOV AH,1 ; 鍵盤有輸入?
28: INT 16H
29: CMP AL,07H ; ='CTRL+G'
30: JE CEND ; 是，完畢
31: MOV DL,0F8H
32: JMP CSNDA ; 送輸入字符
33: CRCV0: ; 接收
34: MOV DL,0FCH ; 通訊控制
35: MOV AX,0E08H ; 暫停中斷
36: OUT DX,AL ; 及顯示
37: MOV DL,0F8H
38: IN AL,DX ; 收字符
39: INT 10H ; 螢屏顯示
40: MOV DL,0FCH
41: MOV AL,0BH
42: JMP CSNDA ; 循環工作
43: CEND:
44: RET ; 完成
看來似乎這樣太小氣，可是所謂藝術，就要具備絲毫不苟且的態度，再說由84個字元變成66個字元，省了近百分之廿，而且，速度也快了。這種程式原本就很精簡，只有訓練有素，追求完美的程式師，才做得到。
另一種做法，便是將重複的過程寫成迴路，約可節省廿幾個字元。但是，由於時間定律限制，通訊程式頗重時效，迴路是否值得，尚要多方面分析，不可輕率決定。
2,迴路的實例：
前面曾經討論過，程式的效率，經常決定於迴路的處理方式及其技巧。其對空間上影響比較小，但是良好的設計理念，常使速度上有高達十倍，甚至百倍的差異，讀者想必已經知道，但是如何能應用已知的技巧，來改進設計的程式呢？
迴路是利用計數器，反複進行相同的程序作業，這種程式，目的就是為了節省空間，相對地，時間上難免有所損失。
因此，在設計迴路時，必須先行考慮清楚: 空間的節省與時間的交換是否值得? 其次，則要充份掌握迴路的特色，要用得恰到好處，不可掉以輕心。
原則上，在迴路中，指令要用得精簡，流程要非常明確，尤其重要的是，應力求避免在迴路中使用緩衝器，最好充份利用暫存器。如果時間效率極為重要，則不妨放棄迴路方式。
有一個顯示程式，目的是要將 16*16點陣字形送到螢幕上。對象是Hercules 640*400的圖形卡，計分四區交互傳送，這是另一個「高科技」界的新鮮奇事，在IBM PC推出時，最高密度的圖形態，只有 640X200點陣，那是遷就電視螢幕的掃描方式，先送單線的水平訊號，再送雙線，故分兩區。Hercules卡為了加高密度，應用Interlace 技術，又在單雙水平掃描線中各加了一行，遂成了四區。
Hercules很適宜中文的顯示，如用 16X16字形，正好顯示25行，每行40字，與英文完全兼容。若希望有一狀態顯示欄，則可用 15X15字形，留出24條線供做狀態欄。
遺憾的是在最需要中文的國內，卻偏愛CGA,EGA 等密度不足的顯示設備。不但售價偏高，功能也不足，弄得不倫不類。
最理想的還是VGA 顯示，計有 640X480之螢幕點陣，不僅空間大，在記憶體中，只有一區，應用非常靈活。
下面，我們先介紹 Hercules 的顯示方法，同時探討迴路的處理方式。
1: ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2: ;HERCULES 中文顯示處理程式。 ;
3: ;輸入參數：SI═點陣字形，DI═螢幕位置。 ;
4: ; DS ═CG，ES= 0B800H(螢幕段）。 ;
5: ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
6: CDSP0:
7: MOV CX,16 ;高16點
8: CDSP1:
9: MOVSW ;移至螢幕上
10: ADD DI,1FFEH ;加一區,每區=2000H
11: JNS CDSP2 ;未超越區限，繼續
12: ADD DI,8050H ;超越區限,換區加行
13: CDSP2:
14: LOOP CDSP1
15: RET
程式到此結束，相當精簡，技巧在第10至12條區限的檢測方式。一般做法是在檢查區限時，用：
ADD DI,1FFEH ; 加區值
CMP DI,8000H ; 最大區限值
JB CDSP2 ; 未超過
SUB DI,8000H ; 減去區限
如此則多了一條４字元的指令，加上４個時鐘脈衝，做16次迴路就損失64個時鐘脈衝值。在全螢幕顯示時，以1,000 個字來算，為數就不少了。
當然，取消了迴路速度還可以加快，其結果，則要增加130 個字元，時間則快了 272個時鐘脈衝，是否值得，就要看實際需要而定了。
另一個方法，要增加２個字元，但可快上36個時鐘脈衝，其法在第11條上：
11: JS CDSP3
12:CDSP2:
13: LOOP CDSP1
14: RET
15:CDSP3:
16: ADD DI,8050H
17: JMP CDSP2
再換一個方法，如果先使 BX 為1FFEH，DX為8050H，則在原程式中，將第10條及12條分別改為:
10: ADD DI,BX
12: ADD DI,DX
這一來，時鐘脈衝快了２個，16次則快更多，如果再加上取消迴路，其意義更大。空間原增加 130字元，現僅94字元，時間則省下 304個時鐘脈衝。如果全螢幕顯示了1,000 個字，在8MHZ頻率下，將會加快 1/25 秒的速度。
在迴路中，如果講求時間效益，應極力避免使用PUSH及POP ，因PUSH需15個時鐘脈衝，而POP 則要12個，兩者相加是27個時鐘脈衝，非常不值得。
解決方法之一是：設法將欲保留之值貯存在沒有用到的暫存器中；再若是固定的常數，也不妨在每次要用時重新置入，祇不過是４個時鐘而已。最麻煩是變數值，除了在設計模組之前，妥當地安排外，別無良策。