|
第五章 套裝軟件製作
程式寫完後，還要加工成為可執行的套裝軟件(Package),一般說來，即使是可以執行的程式，一點錯誤都沒有，離套裝軟件的程度，卻還有一段距離。
當然，程式偵錯也是必經過程之一，有時偵錯與程式寫作可以同時進行。但有經驗的程式師，對全面有了充份的認識，往往會等到程式聯接後再行偵錯。
程式完成後的全面偵錯，最好不要依靠寫程式的人。因為程式師經常不是使用者，他們僅在自己設計的條件下，依其理念進行偵錯。當然這種錯誤必須更正，但最容易發生的錯誤，卻是使用者不小心在輸入時，或運用指令時，違背了程式師的理念。這種錯誤的發生，是不能原諒的，程式本來就是為使用者設計的，如果令使用者不便，程式就失去了應有的價值。
程式的品管，就在於檢測程式是否符合使用者的需求。一般說來，應有專人負責，也有讓寫作手冊的人，兼做品管的工作。這樣可以同時對照手冊所描述的功能及操作方法，檢查兩者之間是否一致。
還有一種常見的品管方式，是在產品完成時，交給完全沒有參與程式設計的第三者，在客觀的立場，作全面的試用，並提出測試報告或建議書。
品管合格了，才是包裝、手冊等最後的工作。這並不是說包裝和手冊要最後才做，相反的，尤其是使用手冊，經常要在程式設計的同時，準備妥當，如此程式師才不會任意所之，脫離主題。
第一節 測試偵錯
不論使用什麼工具，偵錯時一定要有清晰的頭腦，根據所設定的方式，一步一步地查看流程及指令。
每個人都會有獨特的習慣性錯誤，最好每次將自己發生的錯誤記下來，不僅錯誤會漸漸減少，且在錯誤發生時，很容易就能找到。
測試偵錯是非常重要的手段，有人認為第一流的程式師不應該犯錯，即使犯錯，也錯得很少。我的看法不一樣，並非因為我經常犯錯，而且錯得離譜。真正的理由是為了適時掌握正確的思考方向，在編程時，有意無意地忽略一些細節，這樣反而能一氣呵成，不致於再而竭三而衰。
這就像畫圖一樣，有人喜歡先作草圖，有人則習慣由細部畫起。不論個人的風格如何，重要的是最後的成果。
我在寫程式之前，首先考慮全體的結構，再把各處的支架備妥，然後考慮有共同特性之處，便一口氣寫完。而且寫時力求快速，以免失去當時的感覺。等到結構大體完成了，最後才去填補一些不太重要的細節。至於正確與否，則全靠測試偵錯來修正、彌補。
這種寫法要有很強的整體觀念，且對每段程式的性質及功能皆瞭解從何下手。
我由系統程式到應用工具，大大小小的程式寫了不少，對這種寫作方法有很深的體會。唯一的缺點是，程式如果太大，超過20KB，我的記憶力就難以負擔。（年輕人或許不致如此）但其優點則是結構精簡，製作時間極短。以我們的中文系統程式而言，8KB 的程式，連偵錯在內，只花了兩個月的功夫。
然而，在訓練程式師的過程中，我發現到還是循序漸進較好。每次寫完了一段程式，立刻偵錯，此段程式正確了，再寫下一段。除非有絕對的把握，自信沒有問題，否則千萬不要等全部程式都寫完了，再來調試。到那時，如果發現問題，在各段錯綜複雜的程式中，要找到錯誤所在，那是大海撈針了。
程式發生「當機」的情況，常常是 PUSH 及 POP不平衡所致，也有在做迴路時，計數器為負值，以致鎖在其中。如果程式分「段」太多，則要特別注意各「段」改變的情況。
諸如這些細節，最好隨時把編程時的假想值記錄下來，不要太過相信自己的記憶力，時間一長，程式一大，就什麼都忘記了。
還有一點，在偵錯時千萬要養成習慣，記錄追蹤的過程。因為偵錯是一種很瑣碎的工作，很難一次就發現問題所在，第一次應該是第二次改進的經驗。如果不詳加記錄，每次都要從頭做起，將是一種極為痛苦的事。
不妨把偵錯視為猜謎，一種智力的挑戰，在遵守一定的規則下，應該是一種有趣的享受。
第二節 研究改進
想要把程式寫好，一定要不斷地研究、改進，由錯誤中學習，由改進中得到經驗，培養出敏銳的觀察能力和良好的寫作習慣。
在開始時，這種過程需要付出不少時間，但對一位程式師來說，寫程式是終身職業，能不精益求精嗎？
以下舉兩個實例，以說明如何研究改進已完成的程式。
1,指令的運用：
以下面這段通訊處理程式而論，不僅語法及指令完全正確，執行時也毫無錯誤，是不是還可以加以改進呢？
1-1 按照前面規定，說明項中已用簡化的字串：
SND-傳送 RCV-接收 LET-左
RGT-右 VER-直 HOR-橫
1-2 程式師代號為'C'。
1-3 段名省略。
1: CSND0:
2: MOV DX,03FDH ; 輸出埠
3: MOV AL,80H
4: OUT DX,AL ; 輸出指令
5: MOV DX,03F8H ; LSB 速度控制
6: MOV AL,06H ; 速度=19200/秒
7: OUT DX,AL
8: MOV DX,03F9H ; MSB 速度控制
9: MOV AL,0 ; 速度=19200/秒
10: OUT DX,AL
11: MOV DX,03FBH ; 行控制暫存器
12: MOV AL,03H ; NO PARITY,1
; STOP,8
13: OUT DX,AL
14: MOV DX,03FCH ; 通訊控制
15: OUT DX,AL
16: MOV DX,03F9H ; 中斷有效
17: MOV AL,0
18: OUT DX,AL
19: CSND1:
20: MOV DX,03FDH ; 狀態暫存器
21: IN AL,DX
22: TEST AL,10H ; 是否可接收?
23: JNZ CRCV0 ; 可
24: TEST AL,20H ; 通道已清否?
25: JZ CSND1 ; 8250未清
26: MOV AH,1 ; 鍵盤有輸入?
27: INT 16H
28: CMP AL,07H ; ='CTRL+G'
29: JE CEND ; 是，完畢
30: MOV DX,03F8H
31: OUT DX,AL ; 送輸入字符
32: JMP CSND1
33: CRCV0: ; 接收
34: MOV DX,03FCH ; 通訊控制
35: MOV AL,08H ; 暫停中斷
36: OUT DX,AL
37: MOV DX,3F8H
38: IN AL,DX ; 收字符
39: MOV AH,0EH
40: INT 10H ; 螢屏顯示
41: MOV DX,03FCH
42: MOV AL,0BH
43: OUT DX,AL ; 繼續接受
44: JMP CSND1 ; 循環工作
45: CEND:
46: RET ; 完成
本段程式共 84 個字元，非常精簡，但仍然有節省的餘地，要點在DX的數值上。
DX值由 03F8H到 03FDH，可知 DH 之值不變，只需改變 DL 即可。每改變DX一次，需要三個字元，如僅變DL，只需兩個字元。這一指令共用了十一次，除第一次有必要外，其他十次就可以省下10個字元。
再要斤斤計較，還可以搾出二個字元來，在５至８條中，若用INC DX 只需要一個字元。
此外，31，32及43 ,44是浪費的作法，只要在第18條加一標號，就可以省卻兩個字元輸出的指令。另外，還有35及39兩條指令，應該合併，一次即將AX設妥，於是，又省下了一個字元。
先令 DH=3
1: CSEND0:
2: MOV DL,0FDH ; 輸出埠
3: MOV AL,80H
4: OUT DX,AL ; 輸出指令
5: MOV DL,0F8H ; LSB 速度控制
6: MOV AL,06H ; 速度=19200/秒
7: OUT DX,AL
8: INC DX ; MSB 速度控制
9: SUB AL,AL ; 速度=19200/秒
10: OUT DX,AL
11: MOV DL,0FBH ; 行控制暫存器
12: MOV AL,DH ;NO PARITY,1
; STOP,8
13: OUT DX,AL
14: INC DX ; 通訊控制
15: OUT DX,AL
16: MOV DL,0F9H ; 中斷有效
17: SUB AL,AL
18: CSNDA:
19: OUT DX,AL
20: CSND1:
21: MOV DL,0FDH ; 狀態暫存器
22: IN AL,DX
23: TEST AL,10H ; 是否可接收?
24: JNZ CRCV0 ; 可
25: TEST AL,20H ; 通道已清否?
26: JZ CSND1 ; 8250未清
27: MOV AH,1 ; 鍵盤有輸入?
28: INT 16H
29: CMP AL,07H ; ='CTRL+G'
30: JE CEND ; 是，完畢
31: MOV DL,0F8H
32: JMP CSNDA ; 送輸入字符
33: CRCV0: ; 接收
34: MOV DL,0FCH ; 通訊控制
35: MOV AX,0E08H ; 暫停中斷
36: OUT DX,AL ; 及顯示
37: MOV DL,0F8H
38: IN AL,DX ; 收字符
39: INT 10H ; 螢屏顯示
40: MOV DL,0FCH
41: MOV AL,0BH
42: JMP CSNDA ; 循環工作
43: CEND:
44: RET ; 完成
看來似乎這樣太小氣，可是所謂藝術，就要具備絲毫不苟且的態度，再說由84個字元變成66個字元，省了近百分之廿，而且，速度也快了。這種程式原本就很精簡，只有訓練有素，追求完美的程式師，才做得到。
另一種做法，便是將重複的過程寫成迴路，約可節省廿幾個字元。但是，由於時間定律限制，通訊程式頗重時效，迴路是否值得，尚要多方面分析，不可輕率決定。
2,迴路的實例：
前面曾經討論過，程式的效率，經常決定於迴路的處理方式及其技巧。其對空間上影響比較小，但是良好的設計理念，常使速度上有高達十倍，甚至百倍的差異，讀者想必已經知道，但是如何能應用已知的技巧，來改進設計的程式呢？
迴路是利用計數器，反複進行相同的程序作業，這種程式，目的就是為了節省空間，相對地，時間上難免有所損失。
因此，在設計迴路時，必須先行考慮清楚: 空間的節省與時間的交換是否值得? 其次，則要充份掌握迴路的特色，要用得恰到好處，不可掉以輕心。
原則上，在迴路中，指令要用得精簡，流程要非常明確，尤其重要的是，應力求避免在迴路中使用緩衝器，最好充份利用暫存器。如果時間效率極為重要，則不妨放棄迴路方式。
有一個顯示程式，目的是要將 16*16點陣字形送到螢幕上。對象是Hercules 640*400的圖形卡，計分四區交互傳送，這是另一個「高科技」界的新鮮奇事，在IBM PC推出時，最高密度的圖形態，只有 640X200點陣，那是遷就電視螢幕的掃描方式，先送單線的水平訊號，再送雙線，故分兩區。Hercules卡為了加高密度，應用Interlace 技術，又在單雙水平掃描線中各加了一行，遂成了四區。
Hercules很適宜中文的顯示，如用 16X16字形，正好顯示25行，每行40字，與英文完全兼容。若希望有一狀態顯示欄，則可用 15X15字形，留出24條線供做狀態欄。
遺憾的是在最需要中文的國內，卻偏愛CGA,EGA 等密度不足的顯示設備。不但售價偏高，功能也不足，弄得不倫不類。
最理想的還是VGA 顯示，計有 640X480之螢幕點陣，不僅空間大，在記憶體中，只有一區，應用非常靈活。
下面，我們先介紹 Hercules 的顯示方法，同時探討迴路的處理方式。
1: ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2: ;HERCULES 中文顯示處理程式。 ;
3: ;輸入參數：SI＝點陣字形，DI＝螢幕位置。 ;
4: ; DS ＝CG，ES= 0B800H(螢幕段）。 ;
5: ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
6: CDSP0:
7: MOV CX,16 ;高16點
8: CDSP1:
9: MOVSW ;移至螢幕上
10: ADD DI,1FFEH ;加一區,每區=2000H
11: JNS CDSP2 ;未超越區限，繼續
12: ADD DI,8050H ;超越區限,換區加行
13: CDSP2:
14: LOOP CDSP1
15: RET
程式到此結束，相當精簡，技巧在第10至12條區限的檢測方式。一般做法是在檢查區限時，用：
ADD DI,1FFEH ; 加區值
CMP DI,8000H ; 最大區限值
JB CDSP2 ; 未超過
SUB DI,8000H ; 減去區限
如此則多了一條４字元的指令，加上４個時鐘脈衝，做16次迴路就損失64個時鐘脈衝值。在全螢幕顯示時，以1,000 個字來算，為數就不少了。
當然，取消了迴路速度還可以加快，其結果，則要增加130 個字元，時間則快了 272個時鐘脈衝，是否值得，就要看實際需要而定了。
另一個方法，要增加２個字元，但可快上36個時鐘脈衝，其法在第11條上：
11: JS CDSP3
12:CDSP2:
13: LOOP CDSP1
14: RET
15:CDSP3:
16: ADD DI,8050H
17: JMP CDSP2
再換一個方法，如果先使 BX 為1FFEH，DX為8050H，則在原程式中，將第10條及12條分別改為:
10: ADD DI,BX
12: ADD DI,DX
這一來，時鐘脈衝快了２個，16次則快更多，如果再加上取消迴路，其意義更大。空間原增加 130字元，現僅94字元，時間則省下 304個時鐘脈衝。如果全螢幕顯示了1,000 個字，在8MHZ頻率下，將會加快 1/25 秒的速度。
在迴路中，如果講求時間效益，應極力避免使用PUSH及POP ，因PUSH需15個時鐘脈衝，而POP 則要12個，兩者相加是27個時鐘脈衝，非常不值得。
解決方法之一是：設法將欲保留之值貯存在沒有用到的暫存器中；再若是固定的常數，也不妨在每次要用時重新置入，祇不過是４個時鐘而已。最麻煩是變數值，除了在設計模組之前，妥當地安排外，別無良策。
第三節 程式合併
我所見過的各種組合程式雖不算多，但至少有百餘個了。毛病最多的當然是缺乏完整的規劃，其次則是信馬遊韁，一份不折不扣的流水帳！明明大門口在東邊，程式硬要朝西，直到遊完了大觀園，天黑了，才出東門！
這種程式我收集了一大疊，可是舉來做例子，卻心有餘而力不足。原因無他，實在不耐煩照抄一遍，一見到就頭痛！
電腦最強的功能，便是處理繁雜重複的工作，為什麼一般程式師居然存心與電腦爭風吃醋呢？不說別的，光把程式輸入到電腦中，就要花上幾個月寶貴的光陰，真值得這樣做嗎？
有一份程式，足足有四十多頁，我只略作調整，便縮小到十頁，處理速度則快了五倍。為什麼會差這樣遠呢？很簡單，有些人不喜歡用大腦，久而久之，習慣成自然，大腦就生了鐵銹！除了等因奉此，什麼都不會想了。
要想做一個優秀的程式師，第一個條件是不能偷懶，第二個條件則要有分析觀察的習慣，第三個也是最重要的，則是要有追求完美的精神。程式師要像藝術家，不論是自己的或是別人的程式，都要一而再、再而三地玩味改良。
我曾見過一個掃地的婦人，她不管在哪裏，見不得有任何髒亂。這種人才值得尊敬，這種精神是偉大的，與她的職業絲毫無關！
程式寫得不夠精簡，有三個原因，第一個是程式師無能，這種程式能夠寫完，可以運行，已算相當難得了；第二個原因是不懂技巧，硬橋硬馬的幹, 不知什麼是效率，也不知道如何達成。自己寫的程式都不見得看得懂，遑論他人的？第三則是根本缺乏敬業精神，敷衍塞責，這種人我最瞧不起。
寫程式之初，如果把任務瞭解清楚，然後分析因素，分割模組。所有類似的情況都合併到一處，再以變數代替，統一執行。這原本是份內的工作，前述的情況根本不可能發生！
問題是發生了以後怎麼辦呢？我建議最好重寫，如果一定要改，只好採用程式合併的技巧，濃縮一下。
合併的目的是為了增進效率，而合併的方法則因情況不同而異，就像人生了病，必須先查出病因，否則無法下藥。我試著以所知道的一些例証，簡要地解說如後。
一、過程的合併：
要做過程的合併，首先要查明下列各點：
1,首先找出過程類似的，全部移到一堆，如果找不到，那就沒救了。
然而，這種程式要就是太小，根本不可能有類似的情況，再不就是寫作時雜亂無章，信馬遊韁。分明有類似的過程，但沒有共通的原則，無從濃縮。當然，也可能有些程式，因工作量及處理的細節太多，以致無法濃縮。
2,在類似的程式中，找尋相異的指令或流程，再若沒有，那就是重複了，正宜合併。
3,把相異的指令或流程用變數取代，或將不同程式之入口放在暫存器裏。
4,將各程式在應用該流程前，設好變數及使用的暫存器。
5,合併相似的程式段，不同處應用變數取代之。
下面舉一實例，係一繪圖程式之片斷，茲改變原用標題，並將分散在各處若干不同之段，列述如下：
189: MASK PROC NEAR
190: MOV DX,3C4H
191: MOV AL,2
192: OUT DX,AL
193: MOV DX,3C5H
194: MOV AL,PCOLOR
195: OUT DX,AL
196: RET
197: MASK ENDP
…
380: MOV DX,03CEH
381: MOV AL,3
382: OUT DX,AL
383: MOV AL,18H
384: INC DX
385: OUT DX,AL
386: RET
…
490: MOV DX,3CEH
491: MOV AL,3
492: OUT DX,AL
493: MOV DX,3CFH
494: MOV AL,0H
495: OUT DX,AL
496: RET
…
589: CROSS PROC NEAR
590: MOV DX,3C4H
591: MOV AL,2
592: OUT DX,AL
593: INC DX
594: MOV AL,0FH
595: OUT DX,AL
596: RET
597: CROSS ENDP
…
這樣的段落有十多處，看來每個都略有不同，似乎不能合併。然而仔細分析，顯然是程式師訓練不夠，把一個非常有規則的程式，安排得非常紊亂，以致到這個地步。
我們先歸納問題，決定如何合併。第一，上述各段程式，應該統一作為子程式；第二，全部變數只有四個，其中兩個是傳送值，兩個是輸出入埠。後者有連續關係，等於只有一個。因此，在調用此子程式前，應先令DX為輸出入埠，再將變數裝入AX中，一次調用即可。此子程式如下：
300: SUB:
301: OUT DX,AL
302: INC DX
303: MOV AL,AH
304: OUT DX,AL
305: RET
這樣簡短的子程式，有無必要，端視時空的效益而定。不論怎樣整理，都遠比原來的要好。
另外有種情況，更為可怕，就是在鍵盤輸入後，用流程方式，一一比較輸入碼，再一一分別處理。
比如說，為了檢查游標鍵的左、右、上、下等八個方向的移動，以便作相應的處理，程式居然寫成：
100: PP1: MOV AH,0
101: INT 16H
102: CMP AX,4800H ;↑鍵
103: JNE NEXT1
104: CALL MOVDATA ;SET BUFFERS
105: CALL SETDLT ;SET INCREMENT
106: NXT01:
107: CALL DOTUP
108: LOOP NXT01
109: CALL XORDOT ;SET NEW DOT
110: CALL XYDISP ;DISP NEW XXX,YYY
111: JMP PP1
112: NEXT1:
113: CMP AX,5000H ;↓鍵
114: JNE NEXT2
115: CALL MOVDATA ;SET BUFFERS
116: CALL SETDLT ;SET INCREMENT
117: NXT02:
118: CALL DOTDOWN
119: LOOP NXT02
120: CALL XORDOT ;SET NEW DOT
121: CALL XYDISP ;DISP NEW XXX,YYY
122: JMP PP1
123: NEXT2:
124: CMP AX,4B00H ;←鍵
125: JNE NEXT3
…
這段程式總共要檢查八次，才能確定是否有游標移動以及哪個游標在移動。然後，還要一一檢查其他變化，共有十八種有效碼。我實在佩服這種程式師，不但有無比的耐性，還有非凡的想像力，居然能把一段極為簡單平凡的程式，寫得這樣的精彩動人！
如果是我，我會寫得毫無趣味：
100: PP1: SUB AH,AH
101: INT 16H
102: OR AL,AL
103: JNZ PP1 ;AL 非０無效
104: MOV BH,AL
105: MOV BL,AH
106: SUB BL,47H ;最小之字標鍵
107: JLE PP1 ;非處理範圍
108: SHL BX,1
109: CALL FUNC[BX]
110: JMP PP1
這是主流程，程式短，速度快，維護容易，一眼看過去，有什麼錯誤立刻分明。
…
1000: FUNC DW NEXT02 ;↖
1001: DW NEXT0 ;↑
1002: DW NEXT04 ;↗
1003: DW PPRET ;無效
1004: DW NEXT2 ;←
1005: DW PPRET ;無效
1006: DW NEXT4 ;→
1007: DW PPRET ;無效
1008: DW NEXT12 ;↙
1009: DW NEXT1 ;↓
1010: DW NEXT14 ;↘
…
因為這是子程式，加一段、減一段容易非常。
即使是子程式，也有很大的考究，就以前段來說，在 104至110 之間，就值得三思。
104: CALL MOVDATA ;SET BUFFERS
105: CALL SETDLT ;SET INCREMENT
106: NXT01:
107: CALL DOTUP
108: LOOP NXT01
109: CALL XORDOT ;SET NEW DOT
110: CALL XYDISP ;DISP NEW XXX,YYY
首先，104 和105 會重複多次，109 及110 亦然，為什麼不合併為一呢？這也是很常見的程式合併手法，兩次調用合為一次，速度及空間都較為經濟。
在子程式 SETDLT 之前，先調用一次 MOVDATA，另XYDISP也是一樣，首先備妥：
3000: SETDATA:
3001: CALL MOVDATA ;假設本程式有他用
3002: SETDLT:
3003: …
…
3100: XYDIDOT:
3101: CALL XORDOT ; 同上
3102: XYDISP:
3103: …
…
再來設計NEXT0 的子程式：
110: NEXT0:
111: CALL SETDATA
112: NXT01:
113: DOTUP 應搬至此，無需設為子程式。
…
120: LOOP NXT01
121: JMP XYDIDOT ; 如有必要，可先
; 設好參數
這樣合併一下，效果決不止高上十倍，等到真正學會了程式的技巧，寫作時速度也可以提高數倍。
二、分支的處理:
分支是程式中不可避免的手段，使用得好，整個程式氣勢一貫，有行雲流水之妙。
前面的例子根本不具分支的條件，故不能算是分支不良，而是程式師觀念錯誤。
下面再舉一例，由於分支不良，以致程式支離破碎。這是一則計算拋物線的快速程式，妙在沒有用乘除法，也沒有任何函數。其中有幾段是這樣的：
100: BEG00:
101: CMP BP,BUFY
102:? JLE BE7
103: OR CX,CX
104: JG BE20
105: MOV AX,BP
106:? SHL AX,1
107: DEC AX
108: JL BE10
109: BE2:
110: CALL BE1
111: JC BEG00
112: CALL BE3
113: JMP BEG00
…
120: BE14:
121:? LODSW
122: CMP AH,1FH
123: JGE BE141
124: LOOP BE14
125: POP DI
126: POP CX
127: MOV SI,DI
128: JMP BE142
129: BE141:
130: POP DI
131: POP CX
132: MOV SI,DI
…
150: BE10:
151: CALL BE1
152: JMP BEG00
153: BE20:
154: MOV AX,CX
155:? SUB AX,DX
156: SHL AX,1
157: DEC AX
158: JLE BE2
159:? CALL BE3
160: JMP BEG00
161: BE1:
162:? INC DX
163: ADD CX,DX
164: ADD CX,DX
165: INC CX
166: ADD DI,BUFX
167: CMP DI,BX
168: JLE BE1RET
169: CALL BE01
170: SUB DI,BX
171: BE1RET:
172: RET
…
190: BE01:
191:? MOV AL,1
192: CMP [SI+1],AL
193: JNZ BE011
194: INC BYTE PTR [SI+1]
195: RET
…
200: BE141:
…
全部程式並不大，不過一百多條指令，但是稍加改進，卻可以省卻廿多條指令，速度也會加快。重點在於106 到113 的分支錯誤，以致於多出BE10 BE20 BE3 BE01等段程式出來。
照理，BE1 BE3 BE01都不該另設子程式，BE14也應改寫，如此，整個程式就完全不同了。
原來由 105為：
105: MOV AX,BP ;★無必要
106: SHL AX,1 ;★無必要
107: DEC AX ;★無必要
108: JL BE10
109: BE2:
110: CALL BE1 ;★合併後，無需調用
111: JC BEG00 ;★另作分支
112: CALL BE3 ;★也無必要調用
113: JMP BEG00
現改為：
107: BE1: ;原為DEC AX分支處理
108: INC DX ;原161子程式作主流程
109: ADD CX,DX
110: ADD CX,DX
111: INC CX
112: ADD DI,BUFX
113: CMP DI,BX
114: JLE BE11
115: ; CALL BE01 ;本子程式重寫如下：
116: CMP BYTE PTR[SI+1],1
117: JNE BE1A
118: INC BYTE PTR[SI+1]
119: BE1A:
120: SUB DI,BX
121: JC BEG00 ;原111
122: … ;原BE3 程式
…
又 125條三個指令也是分支錯誤，白白浪費。
120: BE14:
121: LODSW
122: CMP AH,1FH
123: JGE BE141
124: LOOP BE14
125: POP DI ;★可以省略
126: POP CX ;★可以省略
127: MOV SI,DI ;★可以省略
128: JMP BE142 ;★可以省略
129: BE141:
130: POP DI
131: POP CX
132: MOV SI,DI ;127移到此
133: JNZ BE142 ;128移到此
134: …
第四節 定案包裝
一、手冊：
手冊寫作本來與程式寫作無關，但由於一般程式師都不知道手冊的重要性，往往程式寫得極佳，而市場口碑卻不良，以致慘遭滑鐵瀘之敗。
實際上，當今市場的趨勢，都傾向於螢幕提示，以致於手冊僅具輔助作用，幫助使用者理解各種功能的發揮而已。
問題就出在這裏，一個功能的介紹、說明，與該功能應用的發揮，完全是不同的層次。「螢幕提示」經常由程式師自行製作，而程式師對文字概念的應用及理解能力，往往並不太高明，其結果可想而知。
手冊應該有專人寫作，這種人既要對文字概念應用裕如，又要充份瞭解電腦的功能。難的是，培養一個程式師，了不起三個月到半年，而一個能達意的作家，起碼需要三至五年。遺憾的是，一般電腦公司沒有這種眼光，以為寫程式需要技術，手冊則隨便找人應付了事。
手冊的重要性，並非僅止於此，一個有價值的程式，一定有週詳的計劃，有製作的藍圖。這種計劃及藍圖，經過文字概念上的整理，應該就是手冊本身。換句話說，有良好規劃的程式，必然是先有手冊作為藍圖，再根據手冊製作程式。
二、版本：
程式完成以後，除非一些特殊的原因，只要有實用價值，必然需要不斷改進、強化。
這一來就面臨版本更新的問題，程式師在製作之初，必須事先考慮週全。不要希望一次把程式寫得盡善美，完整無缺，不僅那是不可能的夢想，也是自找麻煩。
任何一個人，即使是不世天才，也不可能經歷人間所有的事件。而程式所需要適應的範圍，則是動態的、隨著人的知識及經驗不斷增長。因此，一個嶄新的程式一旦問世，就成為人世間的新生事物，人的經驗擴展後，新的需求即接踵而至。剛剛完成的程式，在完成的那一剎，就已成為過去式。
所以在程式規劃時，必須高瞻遠矚，考慮得越是週全，程式的生命力越是旺盛。同時，在另一方面，程式必須交到使用者手中，才有實際的價值。是以如何在週全的規劃，和儘快的完成工作之間，作有效的斟酌取捨，則是個難題。
解決的方法之一，就是利用「版本」觀念，將產品分為數個時期。這樣，不僅產品可以很快地交到使用者手中，而且使用者可以提供其應用經驗的回饋，更有利的，是程式得以不斷地增長、成熟、完善。
有了版本的觀念，還需要對版本的製作有明確的計劃，每一個版本的檔案維護，修訂更正，都要有專人負責。否則，當已經上市的版本還需要修改，而新的版本業已開始設計，若是一個不小心，分不清檔案屬於哪個版本時，其後果之不堪，將非局外人所能領會的了。
三、包裝：
此處所提的「包裝」，不是商業上所謂的如何將產品美化偽裝起來。而是指一個程式交到使用者手中時，應該具備哪些必備的，哪些選用的「配備程式」。
一般大型的應用程式，經常提供很多片磁碟，要先執行一個很複雜的「初始化」程式，才能使用。如果採用組合語言製作，其目的本就是為了節省空間。空間小了，應該可以避免這種多餘的手續。
這就是包裝所要考慮的問題，比如說，在我們的“聚珍整合系統”中，附有如下一些配備程式及手冊：
1,功能、操作提示或手冊：
1-1 sm.hlp：在功能提示態下，說明各功能、操作方式及注意事項。
1-2 smvqoq.exe：聚珍整合系統操作手冊閱覽程式
smvqo1.dat--smvqod.dat ：操作手冊資料檔。
2,smjooh.exe：繁、簡體檔互轉程式
smjooh.tab：繁、簡體轉換對照表。
3,smjopa.exe：本系統與park文書檔資料互轉用。
4,smjob5.exe：為轉換其他系統生成的文書檔資料用。
5,smjib5.exe：轉換dbase iii 資料檔。
這些程式及檔案，都要放在同一片磁碟中，不僅為了方便省事，也可降低成本。
在我們的經驗中，這些工作說來容易，做來卻大費週章。唯有在事先做好妥善的規劃，最後才能省時省事，達到理想的預期效果。
僅以螢幕提示為例，由於資料所佔空間太大，就導致了極大的困難。如果事先有準備，將資料作適當的壓縮，顯然會省卻不少麻煩。
此外，手冊的印刷，磁碟的複製，所有一切應行考慮的，都要事先想清楚。要知道，一個應用軟件，其成本完全在開發及最後的包裝過程，為了成功，代價是必須先付出的。
|